# JAGS model specification begins here...
model{
for (i in 1:plots)
{
  for (j in 1 : spp) 				 #Loop through the species
  {
  muSp[i,j] ~ dgamma(Alph[i], Beta[i])  #muSp is the mean abundance
  lambda[i,j] <- muSp[i,j]   #lambda is the poisson parameter
	x[i,j] ~ dpois(lambda[i,j] )    #x's are data points
	p[i,j]<-lambda[i,j]/tot[i]         #p's are proportional posterior abundances 
	H1[i,j]<--p[i,j]*log(p[i,j])      # A step in calculating Shannon's index
	S1[i,j]<-p[i,j]*p[i,j]            # A step in calculating Simpson's index    
	}
######################################################################
Shan[i]<-sum(H1[i, ])									# Shannon's index
Simp[i]<-sum(S1[i, ])                  # Simpson's index
InvS[i]<-1/Simp[i]                     # The inverse of Simpson's index
Hill[i]<-(InvS[i]-1)/(exp(Shan[i])-1)
PieJ[i]<-Shan[i]/log(spp)
Equi[i]<-exp(Shan[i])/spp
tot[i]<-sum(lambda[i, ])    # A step in calculating proportional abundances           
##################################################################
#######Priors
Alph[i] ~ dexp(1)
Beta[i] ~ dgamma(0.1, 1.0)
Shap[i]<-Alph[i]
Scal[i]<-1/Beta[i]
Mean[i]<-Shap[i]*Scal[i]
Sigm[i]<- sqrt(Shap[i]*Scal[i]*Scal[i])
########################################################
for (n in 1:(i-1)){
DfAl[n,i]<-Alph[n]-Alph[i]
DfSi[n,i]<-Sigm[n]-Sigm[i]
DfSh[n,i]<-Shan[n]-Shan[i]
DfIS[n,i]<-InvS[n]-InvS[i]
DfHi[n,i]<-Hill[n]-Hill[i]
DfPJ[n,i]<-PieJ[n]-PieJ[i]
DfEq[n,i]<-Equi[n]-Equi[i]
 for (j in 1 : spp)
{
 a1[n,i,j]<-abs(lambda[n,j]-lambda[i,j])
 ra1[n,i,j]<-abs(lambda[n,j]/tot[n]-lambda[i,j]/tot[i])
 e1[n,i,j]<-pow((lambda[n,j]-lambda[i,j]),2)
}
CityBlock[n,i]<-sum(a1[n,i, ])
Euclidean[n,i]<-sqrt(sum(e1[n,i, ]))
Sorenson[n,i]<-sum(a1[n,i, ])/(tot[i]+tot[n])
RelSorenson[n,i]<-0.5*sum(ra1[n,i,])
Jacard[n,i]<-2*sum(a1[n,i, ])/(tot[i]+tot[n]+sum(a1[n,i, ]))

}
}
}